Video Scrubber

This workspace uses QuickTime Player as a helper application to allow you to visually locate and set the start time (in point) and end time (out point) of a Video cue in QLab. Here it is in action:

How It Works

This workspace is best used with MIDI triggers, rather than hotkeys, since those will continue to work in QLab even when QuickTime Player is in the foreground. The example workspace also has hotkeys assigned so that you can play around with it even if you don’t have a MIDI device.

The first Script cue, triggered by MIDI note 60 or hotkey “K”, locates the target media for the selected Video cue, and opens that file in QuickTime Player. It also works for Audio cues, although there’s nothing particularly useful about opening audio files in QuickTime Player.

set userApplication to application "QuickTime Player"
tell application id "com.figure53.qlab.3" to tell front workspace
  set selectedCue to last item of (selected as list)
  if q type of selectedCue is in {"Video", "Audio"} then
    set fileTarget to file target of selectedCue
    ignoring application responses
      tell userApplication
        open fileTarget
        activate
        end tell
    end ignoring
  end if
end tell

You can then find the in point you want by scrubbing or using any other control in QuickTime Player. Once you’ve found your in point, the Script cue triggered by MIDI note 62 or “I” transfers the current time from QuickTime Player to the start time of the Video cue in QLab:

tell application "QuickTime Player"
  set thecurrenttime to current time of the front document
end tell

tell application id "com.figure53.qlab.3" to tell front workspace
  set thisCue to last item of (selected as list)
  set inPoint to thecurrenttime
  set start time of thisCue to inPoint
end tell

You then find the out point in QuickTime Player and use MIDI note 64 or “O” to trigger another Script cue, which transfers the current time from QuickTime Player to the end time of the Video cue in QLab:

tell application "QuickTime Player"
  set thecurrenttime to current time of the front document
end tell

tell application id "com.figure53.qlab.3" to tell front workspace
  set thisCue to last item of (selected as list)
  set outPoint to thecurrenttime
  set end time of thisCue to outPoint
end tell

Finally, MIDI note 65 or Key “J” will close the file in QuickTime Player:

set userApplication to application "QuickTime Player"
tell application id "com.figure53.qlab.3" to tell front workspace
  activate
  ignoring application responses
    tell userApplication
      close front document
    end tell
  end ignoring
end tell