Skip A Cue

Sometimes it’s great to be able to skip over a block of cues in the cue list, for instance when a section of a scene is being cut but might be reinstated later. This example allows you to select a block of cues, press a hotkey (in the video it’s ⇧?), and the Script cue which runs will generate Memo and GoTo cues to facilitate automatically skipping the selected cues.

To clear the skip block, select the Memo cue named “SKIP THE NEXT BLOCK OF CUES” at the top of the block, and press the hotkey ⇧Z.

How It Works

These scripts will work with any version of QLab, and only require any reference to application id "com.figure53.qlab.5" to be changed to application id "com.figure53.qlab.3" or application id "com.figure53.qlab.4".

tell application id "com.figure53.qlab.5" to tell front workspace
  try
    set firstcue to first item of (selected as list)
    set cueabove to cue before firstcue
    set lastcue to last item of (selected as list)
    set cuebelow to cue after lastcue
    set playback position of current cue list to cueabove
    set currentcue to last item of (selected as list)
    set continue mode of currentcue to auto_continue
    make type "goto"
    set currentcue to last item of (selected as list)
    set q number of currentcue to ""
    set q name of currentcue to "SKIP THE NEXT BLOCK OF CUES ——————————————"
    set cue target of currentcue to cuebelow
    set playback position of current cue list to lastcue
    make type "memo"
    set currentcue to last item of (selected as list)
    set q number of currentcue to ""
    set q name of currentcue to "END OF SKIPPED CUES ————————————————"
  end try
end tell

The script sets the cue above the selected block to auto-continue, and then inserts a GoTo cue (named to clearly indicate its function) which targets the cue after the selected block. It then inserts a Memo cue at the bottom of the block, and again names it to clearly indicate the end of the skipped cues. The try/end try block in the script is a “get out of jail free card”, which prevents the Script cue from breaking if, for any reason, it cannot complete its operation.

The script to remove a skip block looks like this:

tell application id "com.figure53.qlab.5" to tell front workspace
  try
    set skipcue to first item of (selected as list)
    if the q type of skipcue is "GoTo" then
      set cueabove to cue before skipcue
      set CueID to uniqueID of skipcue
      delete cue id CueID of parent of skipcue
      set playback position of current cue list to cueabove
      set currentcue to last item of (selected as list)
      set continue mode of currentcue to do_not_continue
      set currentcue to playback position of current cue list
      set currentcue to cue after currentcue
      repeat while q name of currentcue is not "END OF SKIPPED CUES ————————————————"
        set currentcue to cue after currentcue
      end repeat
      set CueID to uniqueID of currentcue
      delete cue id CueID of parent of currentcue
    end if
  end try
end tell

It deletes the skip cue and clears the auto continue from the cue above. It then goes through to find the next occurrence of a memo cue to delete a block and deletes that.

You can also explore a method for simply skipping over all disarmed cues in the cookbook entry entitled Space Hijack.